// Knife King
// Coded by Lobe 2007

// About: This was a 10 min side-project i did when i was bored of coding another addon (Zombie Survival).
// Simply, when you knife someone you get all their cash, and a random reward when you spawn.
// Requires: ES Tools - The latest version (At time of typing: v.418)
//           EventScripts V.1.5+


block load
{
  // Config
  es_set kk_adverts 1 "Allow chat adverts?"
  es_set kk_armoradd 60 "How much armor to add to the KnfeKing"
  es_set kk_ctkkskin "player/skinmap/skin name map/terror.mdl" "<- The path to the CT special skin"
  es_set kk_tkkskin "player/skinmap/skin name map/urban.mdl" "<- The path to the CT special skin"
  
  es_set kk_customskins 0 "Are you using custom skins? (1 for yes)"
  es_set kk_customskint "[INSERT PATH HERE]" "<- The download path for the custom T skin"
  es_set kk_customskinct "[INSERT PATH HERE]" "<- The download path for the custom CT skin"
  // End of config
  es_set kk_version "Knife King Version 1.5"
  es_makepublic kk_version
  es_set kk_victim_money 0
  es_set kk_userid 0
  es_set kk_rand 0
  es_xdoblock kk/download
}

block download
{
  es downloadable kk_customskint
  es downloadable kk_customskinct
}

block unload
{
  es_set kk_victim_money 0
  es_set kk_userid 0
  es_set kk_rand 0
  es_set kk_adverts 0
  es_set kk_armoradd 0
  echo [KnifeKing] Script unloaded
  es_msg #multi #green[KnifeKing]#lightgreen KnifeKing has been unloaded!
}

event round_start
{
  if (server_var(kk_adverts) == 1) do
  {
  es_delayed 10 es_msg #multi[KnifeKing]#lightgreen Kill someone with a knife to take their cash and get a random reward!
  }
}

event es_map_start
{
  es_xdoblock kk/download
}

event player_death
{
  if (event_var(weapon) == "knife") do
  {
    es es_msg #multi[KnifeKing]#lightgreen event_var(es_attackername) is the new KnifeKing!
    echo Getting money
    es_getmoney kk_victim_money event_var(userid)
    es est_cash event_var(userid) - server_var(kk_victim_money)
    es_tell event_var(userid) You have lost $server_var(kk_victim_money)!
    es est_cash event_var(attacker) + server_var(kk_victim_money)
    es_tell event_var(attacker) You have gained $server_var(kk_victim_money), and a suprise when you next spawn!
    es_set kk_userid event_var(attacker)
    es_set kk_username event_var(es_attackername)
    // Ok, so we have changed the USERID's around, and its all sorted!
  }
}

event player_say
{
  if (event_var(text) == "/knifeking") do
  {
    if (server_var(kk_userid) notequalto 0) do
    {
      es_msg #multi #green[KnifeKing]#lightgreen The current KnifeKing is server_var(kkusername)
    }
    else do
    {
      es_msg #multi #green[KnifeKing]#lightgreen There is no current knifeking! Knife someone to become the KnifeKing!
    }
  }
}

event player_spawn
{
  if (event_var(userid) == server_var(kk_userid)) do
  {
    es_rand kk_rand 1 5
    es echo The random number is server_var(kk_rand)
    if (server_var(kk_rand) == 1) do
    {
      es est_cash event_var(userid) + 1000
      es_tell event_var(userid) You have been given $1000 for being the knife king!
    }
    if (server_var(kk_rand) == 2) do
    {
      es_give event_var(userid) weapon_awp
      es_tell event_var(userid) You have been given an AWP for being the knife king!
    }
    if (server_var(kk_rand) == 3) do
    {
      es_fire event_var(userid) !self addoutput "gravity 0.5"
      es_tell event_var(userid) You have been given half the normal gravity for being the knife king!
    }
    if (server_var(kk_rand) == 4) do
    {
      es_give event_var(userid) weapon_deagle
      es_tell event_var(userid) You have been given an Deagle for being the knife king!
    }
    if (server_var(kk_rand) == 5) do
    {
      es est_setarmor event_var(userid) server_var(kk_armoradd)
      es_tell event_var(userid) You have been given +server_var(kk_armoradd) armor for being the knife king!
    }
    // Ok. So, lets give him a special skin!
  }
}
