// Simple bot AI to let them use translocators
// The host translocator script must be loaded!

block load
{
  // Register special server-side command
  es_exists _rt_trans_temp command translocator_botuse
  ifx false(_rt_trans_temp) do
  {
    es_xregcmd translocator_botuse translocator/bots/check "Check if bot should use translocator"
  }
}

event player_activate
{
  es_keysetvalue trans_runtime event_var(userid) lastjump "0,0,0"
}

event player_jump
{
  if (event_var(es_steamid) == BOT) do
  {
    es_getplayerprop _rt_trans_vec2 event_var(userid) "CBaseEntity.m_vecOrigin"
    es_keysetvalue trans_runtime event_var(userid) lastjump server_var(_rt_trans_vec2)
    es_delayed 1 translocator_botuse event_var(userid)
  }
}

block check
{
  es_xgetargv _rt_trans_userid 1
  es_keygetvalue _rt_trans_vec1 trans_runtime server_var(_rt_trans_userid) lastjump
  es_getplayerprop _rt_trans_vec2 server_var(_rt_trans_userid) "CBaseEntity.m_vecOrigin"
  es vecmath _rt_trans_temp server_var(_rt_trans_vec1) - server_var(_rt_trans_vec2)
  es vecmath _rt_trans_temp server_var(_rt_trans_temp) length
  if (server_var(_rt_trans_temp) < 50) do
  {
    // bot is stuck
    es_sexec server_var(_rt_trans_userid) trans_throw
    es_delayed 1 es_xsexec server_var(_rt_trans_userid) trans_use
  }
}
