// SRPG Upgrades Sub-Script For SRPG
// Tiago_caza@hotmail.com
//
//

block srpg_give_health
{
es_keygetvalue srpg_temp srpg_users event_var(es_steamid) "Health Lv"
	if (server_var(srpg_temp) > 0) do
	{
	es_xmath srpg_temp * 25
	es est_HealthAdd event_var(userid) server_var(srpg_temp)
	}
}

block srpg_give_armor
{
es_keygetvalue srpg_temp srpg_users event_var(es_steamid) "Armor Lv"
	if (server_var(srpg_temp) > 0) do
	{
	if (server_var(srpg_temp) > 9) do
	{
		es_give event_var(userid) item_assaultsuit
		}
		else do
		{
		es_give event_var(userid) item_kevlar
		}
	es_xmath srpg_temp * 25
	es_xmath srpg_temp + 100
	es est_SetArmor event_var(userid) server_var(srpg_temp)
	}
}

block srpg_give_stealth
{
es_keygetvalue srpg_temp srpg_users event_var(es_steamid) "Stealth Lv"
	if (server_var(srpg_temp) > 0) do
	{
	es_format srpg_temp1 "255-%1*40" server_var(srpg_temp)
	esnq est_math srpg_temp1 server_var(srpg_temp1)
	es est_SetPlayerColor event_var(userid) 255 255 255 server_var(srpg_temp1)
	}
}

block srpg_give_regeneration
{
es_getplayersteamid srpg_repeat_temp server_var(srpg_temp_userid)
es_keygetvalue srpg_repeat_temp1 srpg_users server_var(srpg_repeat_temp) "Regeneration Lv"
	if (server_var(srpg_repeat_temp1) > 0) do
	{
	es_keygetvalue srpg_repeat_temp2 srpg_users server_var(srpg_repeat_temp) "Health Lv"
	if (server_var(srpg_repeat_temp2) != 0) do
	{
		es_xmath srpg_repeat_temp2 * 25
		es_xmath srpg_repeat_temp2 + 100
		}
		else do
		{
		srpg_repeat_temp2 100
		}
	es est_GetHealth srpg_repeat_temp3 server_var(srpg_temp_userid)
	es_math srpg_repeat_temp3 + server_var(srpg_repeat_temp1)
	if (server_var(srpg_repeat_temp3) < server_var(srpg_repeat_temp2)) do
	{
		es est_SetHealth server_var(srpg_temp_userid) server_var(srpg_repeat_temp3)
		}
		else do
		{
		es est_SetHealth server_var(srpg_temp_userid) server_var(srpg_repeat_temp2)
		}
	}
}

block srpg_give_heamount
{
es_keygetvalue srpg_temp srpg_users event_var(es_steamid) "HeGrenades Amount Lv"
	if (server_var(srpg_temp) > 0) do
	{
	es_give event_var(userid) weapon_hegrenade
	if (server_var(srpg_temp) > 1) then es est_SetAmmo event_var(userid) hegrenade server_var(srpg_temp)
	}
}

block srpg_give_vampire
{
es_keygetvalue srpg_temp srpg_users event_var(es_attackersteamid) "Vampire Lv"
	if (server_var(srpg_temp) > 0) do
	{
	es_keygetvalue srpg_temp1 srpg_users event_var(es_attackersteamid) "Health Lv"
	if (server_var(srpg_temp1) != 0) do
	{
		es_xmath srpg_temp1 * 25
		es_xmath srpg_temp1 + 100
		}
		else do
		{
		srpg_temp1 100
		}
	if (event_var(es_attackerhealth) < server_var(srpg_temp1)) do
	{
		es srpg_temp2 event_var(dmg_health)
		if (event_var(dmg_armor) > 0) then es_math srpg_temp2 + event_var(dmg_armor)
		es_format srpg_temp "%1*0.075" server_var(srpg_temp)
		esnq est_math srpg_temp server_var(srpg_temp)
		es_xstring srpg_temp replace "00" ""
		es_format srpg_temp2 "%1*%2+0.5+%3" server_var(srpg_temp2) server_var(srpg_temp) event_var(es_attackerhealth)
		esnq est_math srpg_temp server_var(srpg_temp2)
		es_xstring srpg_temp replace "00" ""
		if (server_var(srpg_temp) > server_var(srpg_temp1)) do
		{
			es est_SetHealth event_var(attacker) server_var(srpg_temp1)
			}
			else do
			{
			es est_SetHealth event_var(attacker) server_var(srpg_temp)
			}
		}
	}
}

block srpg_give_bigblast
{
es_keygetvalue srpg_temp srpg_users event_var(es_attackersteamid) "BigBlast Lv"		
	if (server_var(srpg_temp) > 0) do
	{
	es_xmath srpg_temp * 25
	es_trick dispatcheffect event_var(userid) ManhackSparks  60
	es_give event_var(userid) point_hurt 
	es_fire event_var(userid) !self addoutput "targetname mrdamage" 
	es_fire event_var(userid) point_hurt addoutput "targetname srpg_bigblast_damage" 
	es_format srpg_temp1 "Damage %1" server_var(srpg_temp) 
	es_fire event_var(userid) srpg_bigblast_damage addoutput server_var(srpg_temp1) 
	es_fire event_var(userid) srpg_bigblast_damage addoutput "DamageType 256"
	es_fire event_var(attacker) srpg_bigblast_damage addoutput "DamageTarget mrdamage" 
	es_fire event_var(userid) srpg_bigblast_damage TurnOn 
	es_fire event_var(attacker) srpg_bigblast_damage Hurt
	es_fire event_var(userid) srpg_bigblast_damage kill 
	es_fire event_var(userid) !self addoutput "targetname mrhuman"
    	}
}

block srpg_give_firehe
{
es_keygetvalue srpg_temp srpg_users event_var(es_attackersteamid) "FireGrenades Lv"
	if (server_var(srpg_temp) > 0) do
	{
	es est_Burn event_var(userid) server_var(srpg_temp)
	}
}

block srpg_give_respawn_lives_amount
{
es_keygetvalue srpg_temp1 srpg_users server_var(srpg_temp) "ReSpawn Lives Lv"
	if (server_var(srpg_temp1) > 0) do
	{
	es_keysetvalue srpg_respawn_lives_amount server_var(srpg_temp_userid) server_var(srpg_temp1)
	}
}

block srpg_give_respawn
{
es_keygetvalue srpg_temp srpg_respawn_lives_amount event_var(userid)
	if (server_var(srpg_temp) != 0) do
	{
	es_delayed 0.5 es est_Spawn event_var(userid)
	es_xmath srpg_temp - 1
	es_keysetvalue srpg_respawn_lives_amount event_var(userid) server_var(srpg_temp)
	}
}

block srpg_give_frostpistol
{
es_keygetvalue srpg_temp srpg_users event_var(es_attackersteamid) "FrostPistol Lv"
	if (server_var(srpg_temp) > 0) do
	{
	es_format srpg_temp "%1*0.1" server_var(srpg_temp)
	esnq est_math srpg_temp server_var(srpg_temp)
	es est_Speed event_var(userid) 0.4
	es_delayed server_var(srpg_temp) es est_Speed event_var(userid) 1
	es_xrand srpg_temp 1 4
	es_format srpg_temp "physics/surfaces/tile_impact_bullet%1.wav" server_var(srpg_temp)
	es_emitsound player event_var(userid) server_var(srpg_temp) 1.0 0.8
	}
}

block srpg_give_icestab
{
es_keygetvalue srpg_temp srpg_users event_var(es_attackersteamid) "IceStab Lv"
	if (server_var(srpg_temp) > 0) do
	{
	es est_Freeze event_var(userid) 1
	es_delayed server_var(srpg_temp) es est_Freeze event_var(userid) 0
	es_xrand srpg_temp 1 3
	es_format srpg_temp "physics/glass/glass_impact_bullet%1.wav" server_var(srpg_temp)
	es_emitsound player event_var(userid) server_var(srpg_temp) 1.0 1.0
	}
}

block srpg_give_antiflash
{
es_keygetvalue srpg_temp srpg_users event_var(es_steamid) "AntiFlash Lv"
	if (server_var(srpg_temp) > 0) do
	{
	es_format srpg_temp1 "250-%1*25" server_var(srpg_temp)
	esnq est_math srpg_temp1 server_var(srpg_temp1)
	es_soon es_setplayerprop event_var(userid) "CCSPlayer.m_flFlashMaxAlpha" server_var(srpg_temp1)
	//es_soon es_setplayerprop event_var(userid) "CCSPlayer.m_flFlashDuration" server_var(srpg_temp1)
	}
}

block srpg_give_longjump
{
es_keygetvalue srpg_temp srpg_users event_var(es_steamid) "LongJump Lv"
	if (server_var(srpg_temp) > 0) do
	{
	es_format srpg_temp "0.20*%1+1" server_var(srpg_temp)
	esnq est_math srpg_temp server_var(srpg_temp)
	es_getplayerprop srpg_temp1 event_var(userid) "CCSPlayer.baseclass.localdata.m_vecVelocity[0]"
	es_getplayerprop srpg_temp2 event_var(userid) "CCSPlayer.baseclass.localdata.m_vecVelocity[1]"
	es_format srpg_temp1 "%1*%2" server_var(srpg_temp1) server_var(srpg_temp)
	esnq est_math srpg_temp1 server_var(srpg_temp1)
	es_format srpg_temp2 "%1*%2" server_var(srpg_temp2) server_var(srpg_temp)
	esnq est_math srpg_temp2 server_var(srpg_temp2)
	es_format srpg_temp "%1,%2,0" server_var(srpg_temp1) server_var(srpg_temp2)
	if (server_var(srpg_temp) != "0,0,0") then esnq es_setplayerprop event_var(userid) "CBasePlayer.localdata.m_vecBaseVelocity" server_var(srpg_temp)
	}
}